Results 1 to 8 of 8

Thread: ILS script

  1. #1
    25+ Posting Member
    Join Date
    Mar 2006
    Location
    Italy
    Posts
    38
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    ILS script

    Hi to all,
    finally I'm wiring the panels of pedestal so I using the zip "SIOC sources for Level-D767" for help to fit with my hardware. Now I'm looking for ILS panel script and at least I'm missing anything... I think need follow improve:

    1- CRS support for dual encoder
    2- FREQ support for S4: Standby AC
    3- ILS TEST switch support


    Is possible get these upgrade at script?

    kind regards!!
    Valerio


    ///////////////////////////////////////////////////////////////////////////
    //
    // Title: ILS
    //
    // Manual: 5.12
    // Lekseecon
    // version: 9.0
    //
    // Date: 5 May 2013
    //
    // Author: Nico Kaan
    // The Netherlands
    // www.lekseecon.nl
    //
    // *************************************************************************
    // ILS Frequency

    Var 9001 name ILSFreqLow
    Var 9002 name ILSFreqHigh

    Var 665 Static name ILS_F
    {
    CALL &DecBCD5 &ILS_F
    &D_ILSFreq0 = &Digit0
    &D_ILSFreq1 = &Digit1
    &D_ILSFreq2 = &Digit2
    &D_ILSFreq3 = &Digit3
    &D_ILSFreq4 = &Digit4
    C0 = &Digit4 = -999999
    C1 = &Digit4 = -999998
    IF C0 OR C1
    {
    &O_ILSDP = 0
    }
    ELSE
    {
    &O_ILSDP = 1
    }
    }

    Var 520 Static name ILS_FI // ILS Freq Internal
    {
    L0 = &ILS_FI
    &ILSFreqHigh = DIV L0 10
    &ILSFreqLow = MOD L0 10
    }

    Var 9005 name CalcILSFreq Link SUBRUTINE
    {
    L0 = &ILSFreqHigh * 10 // high * 10
    &ILS_FI = L0 + &ILSFreqLow // + low
    }

    Var 9009 name RO_ILSFL Link IOCARD_ENCODER Device 1 Input 59 Aceleration 1 Type 2
    {
    L0 = TESTBIT &ILS_F 24
    IF L0 = 0 // not blank or lights test, so a valid freqeuncy
    {
    L0 = &RO_ILSFL // * -1
    &ILSFreqLow = ROTATE 0 9 L0
    CALL &CalcILSFreq
    }
    }

    Var 9010 name RO_ILSFH Link IOCARD_ENCODER Device 1 Input 57 Aceleration 1 Type 2
    {
    L0 = TESTBIT &ILS_F 24
    IF L0 = 0 // not blank or lights test, so a valid freqeuncy
    {
    L0 = &RO_ILSFH * 1
    &ILSFreqHigh = LIMIT 0 4 L0
    CALL &CalcILSFreq
    }
    }

    Var 9012 name D_ILSFreq0 Link IOCARD_DISPLAY Device 1 Digit 20 Numbers 1
    Var 9013 name D_ILSFreq1 Link IOCARD_DISPLAY Device 1 Digit 21 Numbers 1
    Var 9014 name D_ILSFreq2 Link IOCARD_DISPLAY Device 1 Digit 22 Numbers 1
    Var 9015 name D_ILSFreq3 Link IOCARD_DISPLAY Device 1 Digit 23 Numbers 1
    Var 9016 name D_ILSFreq4 Link IOCARD_DISPLAY Device 1 Digit 24 Numbers 1

    Var 9020 name O_ILSDP Link IOCARD_OUT Device 1 Output 96

    // *************************************************************************
    // ILS CRS

    Var 522 name ILS_C Static
    {
    CALL &DecBCD3 &ILS_C
    &D_ILSCrs0 = &Digit0
    &D_ILSCrs1 = &Digit1
    &D_ILSCrs2 = &Digit2
    }

    Var 9011 name RO_ILSCRS Link IOCARD_ENCODER Device 1 Input 61 Aceleration 4 Type 2
    {
    L0 = TESTBIT &ILS_C 24
    IF L0 = 0
    {
    L0 = &RO_ILSCRS
    L1 = FROMBCD &ILS_C
    L1 = ROTATE 0 359 L0
    &ILS_C = TOBCD L1
    }
    }

    Var 9017 name D_ILSCrs0 Link IOCARD_DISPLAY Device 1 Digit 25 Numbers 1
    Var 9018 name D_ILSCrs1 Link IOCARD_DISPLAY Device 1 Digit 26 Numbers 1
    Var 9019 name D_ILSCrs2 Link IOCARD_DISPLAY Device 1 Digit 27 Numbers 1

    //
    ///////////////////////////////////////////////////////////////////////////

    Happy landing!!

  2. #2
    2000+ Poster - Never Leaves the Sim kiek's Avatar
    Join Date
    Jan 2007
    Location
    Netherlands
    Posts
    2,198
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: ILS script

    Hi Valerio,

    1) Which digits should each encoder control? I mean if 123, one encoder the 1 and the other 23 or?
    EDIT: From this site I'd say that there is only one rotary encoder for the CRS:
    767-300ER ILS Controls
    2) s4 Support is already available in lekseecon 9.6...
    3) What would that ILS Test Switch do? Just light up all digits as in the Pedestal Lights Test?

    Cheers,
    Nico
    Last edited by kiek; 07-31-2013 at 07:40 AM.

  3. #3
    25+ Posting Member
    Join Date
    Mar 2006
    Location
    Italy
    Posts
    38
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: ILS script

    Hi bud,
    interesting link but....looking at real ILS panels these come with double knobs for CRS set (see pic); as you mean one knob control, from left, two digit (0-35 inner knob) and one knob one digit (0-9 outer knob).

    Attachment 8064


    About switch this should be digits test like in the Pedestal Lights Test.
    Regard "s4 Support" refering to manual only the Var 522 depend from S4-T3 while Var 520 & 521 don't report this..just to known if is correct...


    cheers,
    V.
    Happy landing!!

  4. #4
    2000+ Poster - Never Leaves the Sim kiek's Avatar
    Join Date
    Jan 2007
    Location
    Netherlands
    Posts
    2,198
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: ILS script

    Hi Valerio,
    S_4 support is only applicable to Display variables. Var 520 does not need that, it's just for entering data. Var 521 has no built in Support, use 522 instead.

    About CRS... well MCP Heading and IAS are also just one encoder. Why do you need two encoders to enter just 3 digits?
    But you can easily change the script, there is no change in lekseecon needed... Or do you want me to write that for you?

    Cheers,
    Nico
    Last edited by kiek; 07-31-2013 at 12:37 PM.

  5. #5
    25+ Posting Member
    Join Date
    Mar 2006
    Location
    Italy
    Posts
    38
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: ILS script

    Hi Nico,
    understand about S4 support....about CRS I like as real with dual knobs.. can you provide to write for me the script with dual CRS e ILS TEST switch? ...I owe you one

    thanks,
    V.
    Happy landing!!

  6. #6
    2000+ Poster - Never Leaves the Sim kiek's Avatar
    Join Date
    Jan 2007
    Location
    Netherlands
    Posts
    2,198
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: ILS script

    Hi Valerio,

    I'll put the ILS CRS script at my to-do list, but the ILS Test switch has to be a new variable in lekseecon. That will be in version 10.0 ...

    Nico

  7. #7
    2000+ Poster - Never Leaves the Sim kiek's Avatar
    Join Date
    Jan 2007
    Location
    Netherlands
    Posts
    2,198
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: ILS script

    Hi bud,

    Here it is (and tested), just change it to your hardware numbering:
    Code:
    ///////////////////////////////////////////////////////////////////////////
    //
    //   Title:    ILS CRS with dual rotary encoders
    //             One controlling hundreds
    //             One controlling the last two digits.
    //
    //   Manual:   5.12
    //   Lekseecon
    //   version:  9.6
    //
    //   Date:     31 July 2013
    //
    //   Author:   Nico Kaan
    //             The Netherlands
    //             www.lekseecon.nl
    //
    // *************************************************************************
    // ILS CRS
    
    
    Var 9101 name CRSLow
    Var 9102 name CRSHigh
    
    
    Var 522 name ILS_C Static 
    {
      CALL &DecBCD3 &ILS_C     
      &D_ILSCrs0 = &Digit0
      &D_ILSCrs1 = &Digit1
      &D_ILSCrs2 = &Digit2
      L0 = TESTBIT &ILS_C 24
      IF L0 = 0 
      {
        L0 = FROMBCD &ILS_C
        &CRSHigh = DIV L0 100 
        &CRSLOw = MOD L0 100
      } 
    }
    
    
    Var 9103 name CalcCRS Link SUBRUTINE
    {
      L0 = &CRSHigh * 100             
      L1 = L0 + &CRSLow                
      &ILS_C = TOBCD L1
    }
    
    
    Var 9104 name RO_ILSCRSL Link IOCARD_ENCODER Input 40 Aceleration 2 Type 2     
    {
      L0 = TESTBIT &ILS_C 24
      IF L0 = 0 
      {
        L0 = &RO_ILSCRSL
        &CRSLow = ROTATE 0 59 L0
        CALL &CAlcCRS  
      }     
    }
    
    
    Var 9105 name RO_ILSCRSH Link IOCARD_ENCODER Input 38 Aceleration 1 Type 2     
    {
      L0 = TESTBIT &ILS_C 24
      IF L0 = 0 
      {
        L0 = &RO_ILSCRSH
        &CRSHigh = ROTATE 0 3 L0
        CALL &CAlcCRS  
      }     
    }
    
    
    Var 9106 name D_ILSCrs0 Link IOCARD_DISPLAY Digit 0 Numbers 1
    Var 9107 name D_ILSCrs1 Link IOCARD_DISPLAY Digit 1 Numbers 1
    Var 9108 name D_ILSCrs2 Link IOCARD_DISPLAY Digit 2 Numbers 1
    
    
    //
    ///////////////////////////////////////////////////////////////////////////
    Ciao!
    Nico

  8. #8
    25+ Posting Member
    Join Date
    Mar 2006
    Location
    Italy
    Posts
    38
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: ILS script

    Thaaaaaaaanks!!! ......I'll copy CRS part into ILS script.
    ....waiting for ver 10.0
    A hug,
    V.
    Happy landing!!