Results 1 to 7 of 7

Thread: EFIS code F/O

  1. #1
    Our new friend needs to reach 10 posts to get to the next flight level
    Join Date
    Oct 2009
    Location
    Bezau, Austria
    Posts
    8
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    EFIS code F/O

    Hello!

    I use the Opencockpits 747 EFIS since a few years together with this awesome Software.

    I tried to edit the code for a few times but it never worked out as it should (im a totaly noob in Programming) so i wana ask the Pro's here how to edit the efis code to get it work for the F/O side - i just like flying in the F/O's Seat

    thanks very much,
    Mathias

  2. #2
    2000+ Poster - Never Leaves the Sim kiek's Avatar
    Join Date
    Jan 2007
    Location
    Netherlands
    Posts
    2,200
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: EFIS code F/O

    Hi Matthias,

    That's just a matter of changing the lekseecon variables in the SIOC script 3_EFIS737.txt (for the Captain) into the ones for the FO

    Here it is:
    Code:
    ///////////////////////////////////////////////////////////////////////////
    //
    //   Title:    Opencockpits EFIS737 to be used with the Level-D 767 (FSX + FS9)
    //             as FO side EFIS.
    //
    //   Manual:   div
    //   Lekseecon
    //   version:  9.6
    //
    //   Date:     21 July 2013
    //
    //   Author:   Nico Kaan
    //             The Netherlands
    //             www.lekseecon.nl
    //
    // ************************************************************************
    
    
    Var 9001 name I_VOR1 Link IOCARD_SW Input 36 Device 1
    {
      CALL &VOR1ADF1 
    }
    
    
    Var 9002 name I_ADF1 Link IOCARD_SW Input 37 Device 1
    {
      CALL &VOR1ADF1 
    }
    
    
    Var 9003 name VOR1ADF1 Link SUBRUTINE
    {
      IF &I_VOR1 = 1
      {
        &CapLftAV = 1  // VOR
      }
      ELSE
      {
        IF &I_ADF1 = 1
        {
          &CapLftAV = 0  // ADF
        }
        ELSE // OFF position, not posible in 767, keep the VOR mode 
        { 
          &CapLftAV = 1
        }
      } 
    }
    
    
    Var 9004 name I_VOR2 Link IOCARD_SW Input 18 Device 1
    {
      CALL &VOR2ADF2 
    }
    
    
    Var 9005 name I_ADF2 Link IOCARD_SW Input 19 Device 1
    {
      CALL &VOR2ADF2 
    }
    
    
    Var 9006 name VOR2ADF2 Link SUBRUTINE
    {
      IF &I_VOR2 = 1
      {
        &CapRgtAV = 1  // VOR
      }
      ELSE
      {
        IF &I_ADF2 = 1
        {
          &FORgtAV = 0  // ADF
        }
        ELSE // OFF position, not posible in 767, keep the VOR mode 
        { 
          &FORgtAV = 1
        }
      } 
    }
    
    
    Var 325 name FOLftAV Static  // FOs left  ADF/VOR switch   
    Var 326 name FORgtAV Static  // FOs right ADF/VOR switch   
    
    
    
    
    // ************************************************************************
    // FO Alt Orange Bug
    
    
    Var 9007 name COC
    
    
    Var 9008 name RO_MIN Link IOCARD_ENCODER Input 23 Device 1 Aceleration 1 Type 2 
    {
      L0 = &RO_MIN * -1
      IF L0 > 0
      {
        &FOOBugP = CHANGEBIT 0 &COC
      }
      ELSE
      {
        IF L0 < 0
        {
          &FOOBugM = CHANGEBIT 0 &COC
        }
      }
      &COC = CHANGEBITN 0 &COC
    }
    
    
    Var 332 name FOOBugP Static  
    Var 333 name FOOBugM Static    
    
    
    Var 88 Static
    
    
    Var 9009 name RO_BARO Link IOCARD_ENCODER Input 20 Device 1 Aceleration 1 Type 2  
    {
      L0 = &RO_BARO * -1
      v88 = LIMIT 950 1050 L0
    }
    
    
    
    
    // ************************************************************************
    // master switch
    
    
    Var 266 Static Link IOCARD_SW Input 34 Device 1 Type P    // button FPV
    
    
    
    
    // ************************************************************************
    // Eicas
    
    
    Var 344 Static name Cancel Link IOCARD_SW Input 27 Device 1 Type P
    Var 345 Static name Recall Link IOCARD_SW Input 28 Device 1 Type P
     
    
    
    // compensate for the extra737 Range 5 switch,
    // make sure always one of the 767 ranges is active
    
    
    Var 9011 name Range5 Link IOCARD_SW Device 1 Input 0 Type I   
    {
       CALL &Range5t10
    }
    
    
    Var 9012 name Range10 Link IOCARD_SW Device 1 Input 1 Type I   
    {
       CALL &Range5t10
    }
    
    
    Var 9013 name Range5t10 Link SUBRUTINE
    {
      C0 = &Range5 = 1
      C1 = &Range10 = 1
    
    
      IF C0 OR C1
      {
        &FORange10 = 1
      } 
      ELSE
      {
        &FORange10 = 0
      }
    }
    
    
    Var 480 name FORange10 Static  
    Var 481 Static Link IOCARD_SW Device 1 Input 2 Type I   // 20 
    Var 482 Static Link IOCARD_SW Device 1 Input 3 Type I   // 40  
    Var 483 Static Link IOCARD_SW Device 1 Input 4 Type I   // 80  
    Var 484 Static Link IOCARD_SW Device 1 Input 5 Type I   // 160   
    Var 485 name FORange320 Static 
    
    
    Var 9014 name Range320 Link IOCARD_SW Device 1 Input 6 Type I   
    {
       CALL &Range320t640
    }
    
    
    Var 9015 name Range640 Link IOCARD_SW Device 1 Input 7 Type I  
    {
       CALL &Range320t640
    }
    
    
    Var 9016 name Range320t640 Link SUBRUTINE
    {
      C0 = &Range320 = 1
      C1 = &Range640 = 1
    
    
      IF C0 OR C1
      {
        &FORange320 = 1
      } 
      ELSE
      {
        &FORange320 = 0
      }
    }
    
    
    
    
    Var 487 Static Link IOCARD_SW Device 1 Input 38 Type P  // MTRS button - TCAS on/off
    
    
    Var 488 Static Link IOCARD_SW Device 1 Input 9  Type I  // FULL ILS  
    Var 489 Static Link IOCARD_SW Device 1 Input 10 Type I  // FULL VOR
    Var 492 Static Link IOCARD_SW Device 1 Input 11 Type I  // MAP
    Var 493 Static Link IOCARD_SW Device 1 Input 12 Type I  // PLAN
    
    
    Var 495 Static Link IOCARD_SW Device 1 Input 29 Type P  // WPT      ( I_S3 )
    Var 496 Static Link IOCARD_SW Device 1 Input 30 Type P  // ARPT     ( I_S4 )
    Var 497 Static Link IOCARD_SW Device 1 Input 31 Type P  // RTE DATA ( I_S5 ) 
    Var 498 Static Link IOCARD_SW Device 1 Input 32 Type P  // NAV_AID  ( I_S6 )
    
    
    
    
    // ************************************************************************
    // Chronometer of FOs Clock:
    
    
    Var 339 Static Link IOCARD_SW Device 1 Input 33 Type P
    
    
    //
    ///////////////////////////////////////////////////////////////////////////
    I hope you are able to compile it...

    If not, tell me which OC modules your are using and I'll compile it for you.

    regards,
    Nico

  3. #3
    Our new friend needs to reach 10 posts to get to the next flight level
    Join Date
    Oct 2009
    Location
    Bezau, Austria
    Posts
    8
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: EFIS code F/O

    Hello

    thanks for the quick answer.

    I copied this code into the an txt and wantet to make a ssi with "Config SIOC" but when i open the txt i get the following error:

    Config_SIOC ver 4.3 - By Manuel Velez - www.opencockpits.comOpen file "C:\Programme_XP\lekseecon\ocm\efis\3_EFIS737.txt"
    16:48:54
    Phase 1
    .OK.

    Phase 2
    .OK.


    Phase 3


    ==> &CAPLFTAV

    I pressed ok, saved as "efis.ssi" and copied to /lekseecon/ocm/ssi/, when starting SIOC, the Programm is crashing

    do you know what i made wrong (pretty sure something wrong on my side )

    Mathias

  4. #4
    2000+ Poster - Never Leaves the Sim kiek's Avatar
    Join Date
    Jan 2007
    Location
    Netherlands
    Posts
    2,200
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: EFIS code F/O

    Hi Mathias,
    Oh I see, it did not compile; still some changes are needed, here is an improved text:

    Code:
    ///////////////////////////////////////////////////////////////////////////
    //
    //   Title:    Opencockpits EFIS737 to be used with the Level-D 767 (FSX + FS9)
    //             as FO side EFIS.
    //
    //   Manual:   div
    //   Lekseecon
    //   version:  9.6
    //
    //   Date:     21 July 2013
    //
    //   Author:   Nico Kaan
    //             The Netherlands
    //             www.lekseecon.nl
    //
    // ************************************************************************
    
    
    Var 9001 name I_VOR1 Link IOCARD_SW Input 36 Device 1
    {
      CALL &VOR1ADF1 
    }
    
    
    Var 9002 name I_ADF1 Link IOCARD_SW Input 37 Device 1
    {
      CALL &VOR1ADF1 
    }
    
    
    Var 9003 name VOR1ADF1 Link SUBRUTINE
    {
      IF &I_VOR1 = 1
      {
        &FoLftAV = 1  // VOR
      }
      ELSE
      {
        IF &I_ADF1 = 1
        {
          &FoLftAV = 0  // ADF
        }
        ELSE // OFF position, not posible in 767, keep the VOR mode 
        { 
          &FoLftAV = 1
        }
      } 
    }
    
    
    Var 9004 name I_VOR2 Link IOCARD_SW Input 18 Device 1
    {
      CALL &VOR2ADF2 
    }
    
    
    Var 9005 name I_ADF2 Link IOCARD_SW Input 19 Device 1
    {
      CALL &VOR2ADF2 
    }
    
    
    Var 9006 name VOR2ADF2 Link SUBRUTINE
    {
      IF &I_VOR2 = 1
      {
        &FoRgtAV = 1  // VOR
      }
      ELSE
      {
        IF &I_ADF2 = 1
        {
          &FORgtAV = 0  // ADF
        }
        ELSE // OFF position, not posible in 767, keep the VOR mode 
        { 
          &FORgtAV = 1
        }
      } 
    }
    
    
    Var 325 name FOLftAV Static  // FOs left  ADF/VOR switch   
    Var 326 name FORgtAV Static  // FOs right ADF/VOR switch   
    
    
    
    
    // ************************************************************************
    // FO Alt Orange Bug
    
    
    Var 9007 name COC
    
    
    Var 9008 name RO_MIN Link IOCARD_ENCODER Input 23 Device 1 Aceleration 1 Type 2 
    {
      L0 = &RO_MIN * -1
      IF L0 > 0
      {
        &FOOBugP = CHANGEBIT 0 &COC
      }
      ELSE
      {
        IF L0 < 0
        {
          &FOOBugM = CHANGEBIT 0 &COC
        }
      }
      &COC = CHANGEBITN 0 &COC
    }
    
    
    Var 332 name FOOBugP Static  
    Var 333 name FOOBugM Static    
    
    
    Var 88 Static
    
    
    Var 9009 name RO_BARO Link IOCARD_ENCODER Input 20 Device 1 Aceleration 1 Type 2  
    {
      L0 = &RO_BARO * -1
      v88 = LIMIT 950 1050 L0
    }
    
    
    
    
    // ************************************************************************
    // master switch
    
    
    Var 266 Static Link IOCARD_SW Input 34 Device 1 Type P    // button FPV
    
    
    
    
    // ************************************************************************
    // Eicas
    
    
    Var 344 Static name Cancel Link IOCARD_SW Input 27 Device 1 Type P
    Var 345 Static name Recall Link IOCARD_SW Input 28 Device 1 Type P
     
    
    
    // compensate for the extra737 Range 5 switch,
    // make sure always one of the 767 ranges is active
    
    
    Var 9011 name Range5 Link IOCARD_SW Device 1 Input 0 Type I   
    {
       CALL &Range5t10
    }
    
    
    Var 9012 name Range10 Link IOCARD_SW Device 1 Input 1 Type I   
    {
       CALL &Range5t10
    }
    
    
    Var 9013 name Range5t10 Link SUBRUTINE
    {
      C0 = &Range5 = 1
      C1 = &Range10 = 1
    
    
      IF C0 OR C1
      {
        &FORange10 = 1
      } 
      ELSE
      {
        &FORange10 = 0
      }
    }
    
    
    Var 480 name FORange10 Static  
    Var 481 Static Link IOCARD_SW Device 1 Input 2 Type I   // 20 
    Var 482 Static Link IOCARD_SW Device 1 Input 3 Type I   // 40  
    Var 483 Static Link IOCARD_SW Device 1 Input 4 Type I   // 80  
    Var 484 Static Link IOCARD_SW Device 1 Input 5 Type I   // 160   
    Var 485 name FORange320 Static 
    
    
    Var 9014 name Range320 Link IOCARD_SW Device 1 Input 6 Type I   
    {
       CALL &Range320t640
    }
    
    
    Var 9015 name Range640 Link IOCARD_SW Device 1 Input 7 Type I  
    {
       CALL &Range320t640
    }
    
    
    Var 9016 name Range320t640 Link SUBRUTINE
    {
      C0 = &Range320 = 1
      C1 = &Range640 = 1
    
    
      IF C0 OR C1
      {
        &FORange320 = 1
      } 
      ELSE
      {
        &FORange320 = 0
      }
    }
    
    
    
    
    Var 487 Static Link IOCARD_SW Device 1 Input 38 Type P  // MTRS button - TCAS on/off
    
    
    Var 488 Static Link IOCARD_SW Device 1 Input 9  Type I  // FULL ILS  
    Var 489 Static Link IOCARD_SW Device 1 Input 10 Type I  // FULL VOR
    Var 492 Static Link IOCARD_SW Device 1 Input 11 Type I  // MAP
    Var 493 Static Link IOCARD_SW Device 1 Input 12 Type I  // PLAN
    
    
    Var 495 Static Link IOCARD_SW Device 1 Input 29 Type P  // WPT      ( I_S3 )
    Var 496 Static Link IOCARD_SW Device 1 Input 30 Type P  // ARPT     ( I_S4 )
    Var 497 Static Link IOCARD_SW Device 1 Input 31 Type P  // RTE DATA ( I_S5 ) 
    Var 498 Static Link IOCARD_SW Device 1 Input 32 Type P  // NAV_AID  ( I_S6 )
    
    
    
    
    // ************************************************************************
    // Chronometer of FOs Clock:
    
    
    Var 339 Static Link IOCARD_SW Device 1 Input 33 Type P
    
    
    //
    ///////////////////////////////////////////////////////////////////////////
    Cheers,
    Nico

  5. #5
    Our new friend needs to reach 10 posts to get to the next flight level
    Join Date
    Oct 2009
    Location
    Bezau, Austria
    Posts
    8
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: EFIS code F/O

    Hello Nico!

    Thank you VERY much, working as it should - simply awesome!!

    thanks again for you work!

    Mathias

  6. #6
    2000+ Poster - Never Leaves the Sim kiek's Avatar
    Join Date
    Jan 2007
    Location
    Netherlands
    Posts
    2,200
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: EFIS code F/O

    Quote Originally Posted by Mathias357 View Post
    thanks again for you work!
    Your welcome! Enjoy your EFIS First Officer!.

    Cheers
    Nico

  7. #7
    Our new friend needs to reach 10 posts to get to the next flight level
    Join Date
    Oct 2009
    Location
    Bezau, Austria
    Posts
    8
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: EFIS code F/O

    Thanks Captain!