Results 1 to 2 of 2
  1. #1
    10+ Posting Member
    Join Date
    Apr 2010
    Location
    Wiesbaden, Germany
    Posts
    12
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Functions missing since FMC installtion

    Hi,
    i now got an FMC since christmas and its working fine. But since the installation of it, there are some function not available. My parkbrake are working with the handle, but the light doesn't came on. Also my firetests are not working.
    I checked everything via controlador, iocpconsole and also the config of my sioc file. Everything satis.
    On the other side my gearindication is working normaly.
    When i perform the firetest via the pedestal in the virtual cockpit, the lights are coming on in my firehandles.
    So finaly i think the testswitchs of the firetest and the light of the parkingbrake are not working as they should.
    Any ideas for that.
    regards
    Nils

    Var 0000, Value 0
    {
    &ColdAndDark = 0
    &LTestMIP = 0
    }

    Var 0268 Static
    {
    IF V0268 <> &VOR1Crs // block values coming from rotary
    {
    &VOR1Crs = V0268
    }
    }

    Var 4312, name VOR1Crs
    {
    CALL &OutVOR1Crs
    }

    Var 4321, name OutVOR1Crs, Link SUBRUTINE
    {
    IF &ColdAndDark = 1
    {
    &D_VOR1Crs = -999999
    }
    ELSE
    {
    IF &LTestMIP = 1
    {
    &D_VOR1Crs = 888
    }
    ELSE
    {
    &D_VOR1Crs = &VOR1Crs
    }
    }
    }

    Var 0742 Static
    {
    &O_CMDLLed = TESTBIT V0742 ,0
    &O_CMDCLed = TESTBIT V0742 ,1
    &O_CMDRLed = TESTBIT V0742 ,2
    &IASMACH = TESTBIT V0742 ,3
    &SPDDisplay = TESTBIT V0742 ,4
    &O_LNAVLed = TESTBIT V0742 ,6
    &O_VNAVLed = TESTBIT V0742 ,7
    &O_FLCHLed = TESTBIT V0742 ,8
    &O_HDGHLDLed = TESTBIT V0742 ,9
    &O_VSLed = TESTBIT V0742 ,10
    &VSLed = TESTBIT V0742 ,10
    &O_ALTHLDLed = TESTBIT V0742 ,11
    &O_LOCLed = TESTBIT V0742 ,12
    &O_APPLed = TESTBIT V0742 ,13
    &O_BCRSLed = TESTBIT V0742 ,14
    &O_N1Led = TESTBIT V0742 ,15
    &O_SPDLed = TESTBIT V0742 ,16
    }

    Var 0296 Static
    {
    IF &IAS <> V0296
    {
    &IAS = V0296
    }
    }

    Var 0297 Static
    {
    IF &HDG <> V0297
    {
    &HDG = V0297
    }
    }

    Var 0298 Static
    {
    L0 = V0298
    L1 = DIV L0 ,100
    IF &VS <> L1
    {
    &VS = L1
    }
    }

    Var 0299, static // read/write ALT from/to level-D panel
    {
    CALL &OutALT
    }

    Var 4506, name VSLed
    {
    CALL &OutVS
    }

    Var 4507, name ALT
    {
    CALL &OutALT
    }

    Var 4508, name IAS
    {
    CALL &OutIAS
    }

    Var 4509, name HDG
    {
    CALL &OutHDG
    }

    Var 4510, name VS
    {
    CALL &OutVS
    }

    Var 4511, name SPDDisplay
    {
    CALL &OutIAS
    }

    Var 4512, name IASMACH
    {
    CALL &OutIAS
    }

    Var 4520, name OutMCPButs, Link SUBRUTINE
    {
    IF &ColdAndDark = 1
    {
    &O_AT = 0
    }
    ELSE
    {
    IF &LTestMIP = 1
    {
    &O_AT = 1
    }
    ELSE
    {
    &O_AT = V0292
    }
    }
    }

    Var 4521, name OutIAS, Link SUBRUTINE
    {
    IF &ColdAndDark = 1
    {
    &O_MACHDP = 0
    &D_IAS = -999999
    }
    ELSE
    {
    IF &LTestMIP = 1
    {
    &O_MACHDP = 1
    &D_IAS = 888
    }
    ELSE
    {
    IF &SPDDisplay = 0
    {
    &O_MACHDP = 0
    &D_IAS = -999999
    }
    ELSE
    {
    &O_MACHDP = &IASMACH
    IF &IASMACH = 1
    {
    L0 = DIV &IAS ,10
    &D_IAS = L0
    }
    ELSE
    {
    &D_IAS = &IAS
    }
    }
    }
    }
    }

    Var 4522, name OutHDG, Link SUBRUTINE
    {
    IF &ColdAndDark = 1
    {
    &D_HDG = -999999
    }
    ELSE
    {
    IF &LTestMIP = 1
    {
    &D_HDG = 888
    }
    ELSE
    {
    &D_HDG = &HDG
    }
    }
    }

    Var 4523, name OutVS, Link SUBRUTINE // VS display active or not
    {
    IF &ColdAndDark = 1
    {
    &D_VSS = -999999 // blank
    &D_VS0 = -999999 // blank
    &D_VS = -999999
    }
    ELSE
    {
    IF &LTestMIP = 1
    {
    &D_VSS = 8
    &D_VS0 = 8
    &D_VS = 888
    }
    ELSE
    {
    IF &VSLed = 0
    {
    &D_VSS = -999999 // blank
    &D_VS0 = -999999 // blank
    &D_VS = -999999
    }
    ELSE
    {
    L0 = &VS
    IF &VS < 0
    {
    &D_VSS = -999998 // -
    L0 = L0 * -1
    }
    ELSE
    {
    &D_VSS = -999999 // blank
    }
    L0 = L0 * 100
    IF L0 >= 1000
    {
    &D_VS0 = DIV L0 ,1000
    &D_VS = MOD L0 ,1000
    }
    ELSE
    {
    &D_VS0 = -999999 // blank
    &D_VS = L0
    }
    }
    }
    }
    }

    Var 4524, name OutALT, Link SUBRUTINE
    {
    IF &ColdAndDark = 1
    {
    &D_ALT = -999999
    &D_ALTL0 = -999999
    &D_ALTL00 = -999999
    }
    ELSE
    {
    IF &LTestMIP = 1
    {
    &D_ALT = 888
    &D_ALTL0 = 8
    &D_ALTL00 = 8
    }
    ELSE
    {
    L0 = &ALT * 100
    IF L0 >= 10000
    {
    &D_ALTL0 = DIV L0 ,10000
    L1 = MOD L0 ,10000
    &D_ALTL00 = DIV L1 ,1000
    &D_ALT = MOD L0 ,1000
    }
    ELSE
    {
    &D_ALTL0 = -999999
    IF L0 >= 1000
    {
    &D_ALTL00 = DIV L0 ,1000
    &D_ALT = MOD L0 ,1000
    }
    ELSE
    {
    &D_ALTL00 = -999999
    &D_ALT = L0
    }
    }
    }
    }
    }

    Var 0272 Static
    {
    IF V0272 <> &VOR2Crs
    {
    &VOR2Crs = V0272
    }
    }

    Var 4313, name VOR2Crs
    {
    CALL &OutVOR2Crs
    }

    Var 4322, name OutVOR2Crs, Link SUBRUTINE
    {
    IF &ColdAndDark = 1
    {
    &D_VOR2Crs = -999999
    }
    ELSE
    {
    IF &LTestMIP = 1
    {
    &D_VOR2Crs = 888
    }
    ELSE
    {
    &D_VOR2Crs = &VOR2Crs
    }
    }
    }

    Var 4370, name D_VOR1Crs, Link IOCARD_DISPLAY, Digit 0, Numbers 3

    Var 4571, name D_IAS, Link IOCARD_DISPLAY, Digit 3, Numbers 3

    Var 4572, name D_HDG, Link IOCARD_DISPLAY, Digit 6, Numbers 3

    Var 4573, name D_VS, Link IOCARD_DISPLAY, Digit 14, Numbers 3

    Var 4578, name D_VS0, Link IOCARD_DISPLAY, Digit 17, Numbers 1

    Var 4574, name D_VSS, Link IOCARD_DISPLAY, Digit 18, Numbers 1

    Var 4575, name D_ALT, Link IOCARD_DISPLAY, Digit 9, Numbers 3

    Var 4576, name D_ALTL00, Link IOCARD_DISPLAY, Digit 12, Numbers 1

    Var 4577, name D_ALTL0, Link IOCARD_DISPLAY, Digit 13, Numbers 1

    Var 4376, name D_VOR2Crs, Link IOCARD_DISPLAY, Digit 19, Numbers 3

    Var 4580, name O_N1Led, Link IOCARD_OUT, Output 21

    Var 4581, name O_SPDLed, Link IOCARD_OUT, Output 23

    Var 4582, name O_LNAVLed, Link IOCARD_OUT, Output 29

    Var 4583, name O_VNAVLed, Link IOCARD_OUT, Output 25

    Var 4584, name O_FLCHLed, Link IOCARD_OUT, Output 24

    Var 4585, name O_HDGHLDLed, Link IOCARD_OUT, Output 26

    Var 4586, name O_VSLed, Link IOCARD_OUT, Output 31

    Var 4587, name O_ALTHLDLed, Link IOCARD_OUT, Output 30

    Var 4588, name O_BCRSLed, Link IOCARD_OUT, Output 32 // Led CWSA is used as BCRS

    Var 4589, name O_LOCLed, Link IOCARD_OUT, Output 28

    Var 4590, name O_APPLed, Link IOCARD_OUT, Output 27

    Var 4591, name O_CMDLLed, Link IOCARD_OUT, Output 33

    Var 4592, name O_CMDCLed, Link IOCARD_OUT, Output 35

    Var 4593, name O_CMDRLed, Link IOCARD_OUT, Output 34 // Led CWSB is used as CMD R

    Var 4594, name O_AT, Link IOCARD_OUT, Output 22

    Var 4596, name O_MACHDP, Link IOCARD_OUT, Output 20

    Var 0275 Static, Link IOCARD_SW, Input 21, Type P

    Var 0276 Static, Link IOCARD_SW, Input 19, Type P

    Var 0277 Static, Link IOCARD_SW, Input 18, Type P // CWS B is used as CMD R

    Var 0278 Static, Link IOCARD_SW, Input 13, Type P

    Var 0279 Static, Link IOCARD_SW, Device 1, Input 49, Type P // SPD Intervention

    Var 0280 Static, Link IOCARD_SW, Input 32, Type P

    Var 0281 Static, Link IOCARD_SW, Input 31, Type P

    Var 0282 Static, Link IOCARD_SW, Input 23, Type P

    Var 0283 Static, Link IOCARD_SW, Input 28, Type P

    Var 0284 Static, Link IOCARD_SW, Device 1, Input 48, Type P // HDG SEL

    Var 0285 Static, Link IOCARD_SW, Input 27, Type P

    Var 0286 Static, Link IOCARD_SW, Input 30, Type P

    Var 0287 Static, Link IOCARD_SW, Input 29, Type P

    Var 0288 Static, Link IOCARD_SW, Input 20, Type I

    Var 0289 Static, Link IOCARD_SW, Input 25, Type P

    Var 0290 Static, Link IOCARD_SW, Input 24, Type P

    Var 0291 Static, Link IOCARD_SW, Input 22, Type P

    Var 0292 Static, Link IOCARD_SW, Input 33, Type I
    {
    IF &ColdAndDark = 0
    {
    &O_AT = V0292
    }
    }

    Var 0293 Static, Link IOCARD_SW, Input 15, Type I

    Var 0294 Static, Link IOCARD_SW, Input 16, Type I

    Var 0295 Static, Link IOCARD_SW, Input 14, Type I

    Var 4640, name RO_VOR1CRS, Link IOCARD_ENCODER, Input 4, Aceleration 2, Type 2
    {
    L0 = &RO_VOR1CRS * -1 // turning right should be plus
    &VOR1Crs = ROTATE 0 ,359 ,L0
    V0268 = &VOR1Crs // to panel
    }

    Var 4641, name RO_Ias, Link IOCARD_ENCODER, Input 0, Aceleration 2, Type 2
    {
    IF &SPDDisplay = 1 // Respond only when Ias/Mach display on ..
    {
    L0 = &RO_Ias * -1 // turning right should be plus
    IF &IASMACH = 0
    {
    &IAS = LIMIT 100 ,399 ,L0
    }
    ELSE
    {
    &IAS = LIMIT 400 ,950 ,L0
    }
    V0296 = &IAS // to panel
    }
    }

    Var 4642, name RO_HDG, Link IOCARD_ENCODER, Input 6, Aceleration 2, Type 2
    {
    L0 = &RO_HDG * -1 // turning right should be plus
    &HDG = ROTATE 0 ,359 ,L0
    V0297 = &HDG // to panel
    }

    Var 4643, name RO_VS, Link IOCARD_ENCODER, Input 11, Aceleration 2, Type 2
    {
    IF &VSLed = 1 // Respond only when in VS mode ...
    {
    L0 = &RO_VS * -1 // turning right should be plus
    &VS = LIMIT -99 ,99 ,L0
    V0298 = &VS * 100 // to panel
    }
    }

    Var 4644, name RO_ALT, Link IOCARD_ENCODER, Input 2, Aceleration 2, Type 2
    {
    L0 = &RO_ALT * -1 // turning right should be plus
    &ALT = LIMIT 0 ,640 ,L0
    V0299 = &ALT
    }

    Var 4645, name RO_VOR2CRS, Link IOCARD_ENCODER, Input 9, Aceleration 2, Type 2
    {
    L0 = &RO_VOR2CRS * -1 // turning right should be plus
    &VOR2Crs = ROTATE 0 ,359 ,L0
    V0272 = &VOR2Crs // to panel
    }

    Var 0782 Static, name FI_Panel
    {
    &ColdAndDark = TESTBIT &FI_Panel ,0
    }

    Var 1050, name ColdAndDark
    {
    CALL &Refresh
    }

    Var 1055, name Refresh, Link SUBRUTINE
    {
    CALL &OutIAS
    CALL &OutHDG
    CALL &OutVS
    CALL &OutALT
    CALL &OutMCPButs
    CALL &OutVOR1Crs
    CALL &OutVOR2Crs
    CALL &OutParkBrake
    }

    Var 0580 Static, name LTestMIP
    {
    CALL &Refresh
    }

    Var 0508 Static, name LSCPbr

    Var 0509 Static, Link IOCARD_SW, Device 1, Input 37, Type I

    Var 7700, name FI_ParkBrake, Link FSUIPC_IN, Offset $0BC8, Length 2
    {
    C0 = &FI_ParkBrake = 0
    IF C0
    {
    &ParkBrake = 0
    }
    ELSE
    {
    &ParkBrake = 1
    }
    }

    Var 7710, name ParkBrake
    {
    &LSCPbr = &ParkBrake
    CALL &OutParkBrake
    }

    Var 7720, name OutParkBrake, Link SUBRUTINE
    {
    IF &ColdAndDark = 1
    {
    &O_ParkBrake = 0
    }
    ELSE
    {
    IF &LTestMIP = 1
    {
    &O_ParkBrake = 1
    }
    ELSE
    {
    &O_ParkBrake = &ParkBrake
    }
    }
    }

    Var 7780, name O_ParkBrake, Link IOCARD_OUT, Device 1, Output 11

    Var 0505 Static, Link IOCARD_SW, Device 1, Input 43, Type I //

    Var 0506 Static, Link IOCARD_SW, Device 1, Input 38, Type I

    Var 0507 Static, Link IOCARD_SW, Device 1, Input 39, Type I

    Var 0503 Static, Link IOCARD_SW, Device 1, Input 40, Type I

    Var 0504 Static, Link IOCARD_SW, Device 1, Input 44, Type I

    Var 0249 Static, Link IOCARD_SW, Device 1, Input 0, Type I // light override

    Var 0250 Static, Link IOCARD_SW, Device 1, Input 6, Type I // Position Lights

    Var 0251 Static, Link IOCARD_SW, Device 1, Input 5, Type I // Anticollisionlights red

    Var 0252 Static, Link IOCARD_SW, Device 1, Input 11, Type I // Anticollisionlights white

    Var 0254 Static, Link IOCARD_SW, Device 1, Input 10, Type I // Logo Lights

    Var 0260 Static, Link IOCARD_SW, Device 1, Input 4, Type I

    Var 0261 Static, Link IOCARD_SW, Device 1, Input 1, Type I

    Var 0262 Static, Link IOCARD_SW, Device 1, Input 2, Type I

    Var 0263 Static, Link IOCARD_SW, Device 1, Input 3, Type I

    Var 0264 Static, Link IOCARD_SW, Device 1, Input 8, Type I

    Var 0265 Static, Link IOCARD_SW, Device 1, Input 7, Type I

    Var 0781 Static
    {
    &O_LENGFire = TESTBIT V0781 ,0
    &O_RENGfire = TESTBIT V0781 ,1
    }

    Var 0849 Static
    {
    &O_LENGOVHT = TESTBIT V0849 ,6
    &O_LENGDisc = TESTBIT V0849 ,0
    &O_RENGOVHT = TESTBIT V0849 ,7
    &O_RENGDisc = TESTBIT V0849 ,1
    }

    Var 9001, name O_LENGFire, Link IOCARD_OUT, Device 1, Output 13

    Var 9002, name O_RENGfire, Link IOCARD_OUT, Device 1, Output 12

    Var 9003, name O_LENGOVHT, Link IOCARD_OUT, Device 1, Output 45

    Var 9004, name O_LENGDisc, Link IOCARD_OUT, Device 1, Output 46

    Var 9005, name O_RENGOVHT, Link IOCARD_OUT, Device 1, Output 47

    Var 9006, name O_RENGDisc, Link IOCARD_OUT, Device 1, Output 48

    Var 0559, Link IOCARD_SW, Device 1, Input 46, Type I // Eng fire test

    Var 0560, Link IOCARD_SW, Device 1, Input 47, Type I // wheel well fire test


    Var 764, Static
    {
    &O_Nose = TESTBIT v764 ,0
    &O_Left = TESTBIT v764 ,1
    &O_Right = TESTBIT v764 ,2
    &O_Gear = TESTBIT v764 ,3
    &O_Doors = TESTBIT v764 ,4
    }

    Var 5980 name O_Doors Link IOCARD_OUT, Device 1, Output 20

    Var 5981 name O_Gear Link IOCARD_OUT, Device 1, Output 18

    Var 5982 name O_Nose Link IOCARD_OUT, Device 1, Output 14

    Var 5983 name O_Left Link IOCARD_OUT, Device 1, Output 17

    Var 5984 name O_Right Link IOCARD_OUT, Device 1, Output 16

    // Gear Lever:

    Var 368 Static Link IOCARD_SW, Device 1, Input 52 Type I // Gear Down
    Var 369 Static Link IOCARD_SW, Device 1, Input 53 Type I // Gear off
    Var 370 Static Link IOCARD_SW, Device 1, Input 45 Type I // Gear Up

    Var 739 Static
    {
    &O_Warning = TESTBIT v739 0
    &O_Caution = TESTBIT v739 1
    }

    Var 9007 name O_Warning Link IOCARD_OUT, Device 1, Output 15
    Var 9008 name O_Caution Link IOCARD_OUT, Device 1, Output 19


    // master switch

    Var 266 Static Link IOCARD_SW,Device 1, Input 51 Type P // master reset

    Var 9012 Value 0
    {
    &LowEicas = 1
    }

    Var 344 Static name Cancel Link IOCARD_SW Input 89 Type P
    Var 345 Static name Recall Link IOCARD_SW Input 90 Type P

    Var 346 Static
    Var 347 Static
    Var 348 Static

    Var 9011 name LOwEicas
    {
    IF &LowEicas = 0
    {
    v346 = 1
    v347 = 0
    v348 = 0
    }
    ELSE
    {
    IF &LowEicas = 1
    {
    v346 = 0
    v347 = 1
    v348 = 0
    }
    ELSE
    {
    v346 = 0
    v347 = 0
    v348 = 1
    }
    }
    }
    Var 9009 name EicEngines Link IOCARD_SW, device 1, Input 42 Type I // met push button
    {
    IF &EicEngines = 1
    {
    IF &LowEicas = 1
    {
    &LowEicas = 0
    }
    ELSE
    {
    &LowEicas = 1
    }
    }
    }

    Var 9010 name EicStatus Link IOCARD_SW, Device 1, Input 41 Type I // met push button
    {
    IF &EicStatus = 1
    {
    IF &LowEicas = 2
    {
    &LowEicas = 0
    }
    ELSE
    {
    &LowEicas = 2
    }
    }
    }


    // *************************************************************************
    // FMC

    Var 6000 Static name Key Link USB_KEYS
    {
    IF &Key != 0
    {
    IF &Key <= 40 // split it up in two halves, for a faster search.
    {
    IF &Key <= 20 // and another split up in two halves ...
    {
    IF &Key = 1
    {
    &LET_CLR = CHANGEBITN 0 &LET_CLR
    }
    IF &Key = 2
    {
    &LET_SLASH = CHANGEBITN 0 &LET_SLASH
    }
    IF &Key = 3
    {
    &LET_DEL = CHANGEBITN 0 &LET_DEL
    }
    IF &Key = 4
    {
    &LET_SP = CHANGEBITN 0 &LET_SP
    }
    IF &Key = 5
    {
    &LET_Z = CHANGEBITN 0 &LET_Z
    }
    IF &Key = 6
    {
    &PLUS_MINUS = CHANGEBITN 0 &PLUS_MINUS
    }
    IF &Key = 7
    {
    &NUM_0 = CHANGEBITN 0 &NUM_0
    }
    IF &Key = 8
    {
    &NUM_DP = CHANGEBITN 0 &NUM_DP
    }
    IF &Key = 9
    {
    &LET_Y = CHANGEBITN 0 &LET_Y
    }
    IF &Key = 10
    {
    &LET_X = CHANGEBITN 0 &LET_X
    }
    IF &Key = 11
    {
    &LET_W = CHANGEBITN 0 &LET_W
    }
    IF &Key = 12
    {
    &LET_V = CHANGEBITN 0 &LET_V
    }
    IF &Key = 13
    {
    &LET_U = CHANGEBITN 0 &LET_U
    }
    IF &Key = 14
    {
    &NUM_9 = CHANGEBITN 0 &NUM_9
    }
    IF &Key = 15
    {
    &NUM_8 = CHANGEBITN 0 &NUM_8
    }
    IF &Key = 16
    {
    &NUM_7 = CHANGEBITN 0 &NUM_7
    }
    IF &Key = 17
    {
    &LET_T = CHANGEBITN 0 &LET_T
    }
    IF &Key = 18
    {
    &LET_S = CHANGEBITN 0 &LET_S
    }
    IF &Key = 19
    {
    &LET_R = CHANGEBITN 0 &LET_R
    }
    IF &Key = 20
    {
    &LET_Q = CHANGEBITN 0 &LET_Q
    }
    }
    ELSE
    {
    IF &Key = 21
    {
    &LET_P = CHANGEBITN 0 &LET_P
    }
    IF &Key = 22
    {
    &NUM_6 = CHANGEBITN 0 &NUM_6
    }
    IF &Key = 23
    {
    &NUM_5 = CHANGEBITN 0 &NUM_5
    }
    IF &Key = 24
    {
    &NUM_4 = CHANGEBITN 0 &NUM_4
    }
    IF &Key = 25
    {
    &LET_O = CHANGEBITN 0 &LET_O
    }
    IF &Key = 26
    {
    &LET_N = CHANGEBITN 0 &LET_N
    }
    IF &Key = 27
    {
    &LET_M = CHANGEBITN 0 &LET_M
    }
    IF &Key = 28
    {
    &LET_L = CHANGEBITN 0 &LET_L
    }
    IF &Key = 29
    {
    &LET_K = CHANGEBITN 0 &LET_K
    }
    IF &Key = 30
    {
    &NUM_3 = CHANGEBITN 0 &NUM_3
    }
    IF &Key = 31
    {
    &NUM_2 = CHANGEBITN 0 &NUM_2
    }
    IF &Key = 32
    {
    &NUM_1 = CHANGEBITN 0 &NUM_1
    }

    // 33 .. 39
    }
    }
    ELSE
    {
    IF &Key <= 70
    {

    // 41 .. 48

    IF &Key = 49
    {
    &LET_J = CHANGEBITN 0 &LET_J
    }
    IF &Key = 50
    {
    &LET_I = CHANGEBITN 0 &LET_I
    }
    IF &Key = 51
    {
    &LET_H = CHANGEBITN 0 &LET_H
    }
    IF &Key = 52
    {
    &LET_G = CHANGEBITN 0 &LET_G
    }
    IF &Key = 53
    {
    &LET_F = CHANGEBITN 0 &LET_F
    }
    IF &Key = 54
    {
    &NEXT_PAGE = CHANGEBITN 0 &NEXT_PAGE
    }
    IF &Key = 55
    {
    &PREV_PAGE = CHANGEBITN 0 &PREV_PAGE
    }
    IF &Key = 56
    {
    &LSKL1 = CHANGEBITN 0 &LSKL1
    }
    IF &Key = 57
    {
    &LET_E = CHANGEBITN 0 &LET_E
    }
    IF &Key = 58
    {
    &LET_D = CHANGEBITN 0 &LET_D
    }
    IF &Key = 59
    {
    &LET_C = CHANGEBITN 0 &LET_C
    }
    IF &Key = 60
    {
    &LET_B = CHANGEBITN 0 &LET_B
    }
    IF &Key = 61
    {
    &LET_A = CHANGEBITN 0 &LET_A
    }
    IF &Key = 62
    {
    &NAV_RAD = CHANGEBITN 0 &NAV_RAD
    }
    IF &Key = 63
    {
    &MENU = CHANGEBITN 0 &MENU
    }
    IF &Key = 64
    {
    &LSKL2 = CHANGEBITN 0 &LSKL2
    }

    // 65

    IF &Key = 66
    {
    &EXEC = CHANGEBITN 0 &EXEC
    }
    IF &Key = 67
    {
    &PROG = CHANGEBITN 0 &PROG
    }
    IF &Key = 68
    {
    &FMC_COMM = CHANGEBITN 0 &FMC_COMM
    }
    IF &Key = 69
    {
    &HOLD = CHANGEBITN 0 &HOLD
    }
    IF &Key = 70
    {
    &LEGS = CHANGEBITN 0 &LEGS
    }
    }
    ELSE
    {
    IF &Key = 71
    {
    &FIX = CHANGEBITN 0 &FIX
    }
    IF &Key = 72
    {
    &LSKL3 = CHANGEBITN 0 &LSKL3
    }

    // 73

    IF &Key = 74
    {
    &LSKR6 = CHANGEBITN 0 &LSKR6
    }
    IF &Key = 75
    {
    &VNAV = CHANGEBITN 0 &VNAV
    }
    IF &Key = 76
    {
    &ATC = CHANGEBITN 0 &ATC
    }
    IF &Key = 77
    {
    &DEP_ARR = CHANGEBITN 0 &DEP_ARR
    }
    IF &Key = 78
    {
    &RTE = CHANGEBITN 0 &RTE
    }
    IF &Key = 79
    {
    &INIT_REF = CHANGEBITN 0 &INIT_REF
    }
    IF &Key = 80
    {
    &LSKL4 = CHANGEBITN 0 &LSKL4
    }

    // 81

    IF &Key = 82
    {
    &LSKR5 = CHANGEBITN 0 &LSKR5
    }
    IF &Key = 83
    {
    &LSKR4 = CHANGEBITN 0 &LSKR4
    }
    IF &Key = 84
    {
    &LSKR3 = CHANGEBITN 0 &LSKR3
    }
    IF &Key = 85
    {
    &LSKR2 = CHANGEBITN 0 &LSKR2
    }
    IF &Key = 86
    {
    &LSKR1 = CHANGEBITN 0 &LSKR1
    }
    IF &Key = 87
    {
    &LSKL6 = CHANGEBITN 0 &LSKL6
    }
    IF &Key = 88
    {
    &LSKL5 = CHANGEBITN 0 &LSKL5
    }
    }
    }
    }
    }


    Var 387 Static name LSKL1
    Var 388 Static name LSKL2
    Var 389 Static name LSKL3
    Var 390 Static name LSKL4
    Var 391 Static name LSKL5
    Var 392 Static name LSKL6
    Var 393 Static name LSKR1
    Var 394 Static name LSKR2
    Var 395 Static name LSKR3
    Var 396 Static name LSKR4
    Var 397 Static name LSKR5
    Var 398 Static name LSKR6
    Var 399 Static name INIT_REF
    Var 400 Static name RTE
    Var 401 Static name DEP_ARR
    Var 402 Static name ATC
    Var 403 Static name VNAV
    Var 404 Static name FIX
    Var 405 Static name LEGS
    Var 406 Static name HOLD
    Var 407 Static name FMC_COMM
    Var 408 Static name PROG
    Var 409 Static name EXEC
    Var 410 Static name MENU
    Var 411 Static name NAV_RAD
    Var 412 Static name PREV_PAGE
    Var 413 Static name NEXT_PAGE

    Var 414 Static name LET_A
    Var 415 Static name LET_B
    Var 416 Static name LET_C
    Var 417 Static name LET_D
    Var 418 Static name LET_E
    Var 419 Static name LET_F
    Var 420 Static name LET_G
    Var 421 Static name LET_H
    Var 422 Static name LET_I
    Var 423 Static name LET_J
    Var 424 Static name LET_K
    Var 425 Static name LET_L
    Var 426 Static name LET_M
    Var 427 Static name LET_N
    Var 428 Static name LET_O
    Var 429 Static name LET_P
    Var 430 Static name LET_Q
    Var 431 Static name LET_R
    Var 432 Static name LET_S
    Var 433 Static name LET_T
    Var 434 Static name LET_U
    Var 435 Static name LET_V
    Var 436 Static name LET_W
    Var 437 Static name LET_X
    Var 438 Static name LET_Y
    Var 439 Static name LET_Z
    Var 440 Static name LET_SP
    Var 441 Static name LET_DEL
    Var 442 Static name LET_SLASH
    Var 443 Static name LET_CLR

    Var 444 Static name NUM_1
    Var 445 Static name NUM_2
    Var 446 Static name NUM_3
    Var 447 Static name NUM_4
    Var 448 Static name NUM_5
    Var 449 Static name NUM_6
    Var 450 Static name NUM_7
    Var 451 Static name NUM_8
    Var 452 Static name NUM_9
    Var 453 Static name NUM_DP
    Var 454 Static name NUM_0
    Var 455 Static name PLUS_MINUS

  2. #2
    2000+ Poster - Never Leaves the Sim kiek's Avatar
    Join Date
    Jan 2007
    Location
    Netherlands
    Posts
    2,202
    Contribute If you enjoy reading the
    content here, click the below
    image to support MyCockpit site.
    Click Here To Contribute To Our Site

    Re: Functions missing since FMC installtion

    Hi,

    Your Fire Test Switches do not work because you have not added keyword Static to their declarations ...

    Code:
    Var 0559, Link IOCARD_SW, Device 1, Input 46, Type I // Eng fire test
    Var 0560, Link IOCARD_SW, Device 1, Input 47, Type I // wheel well fire test
    Lekseecon will not recognise 559 and 560. You can see that too in the lekseecon_log.txt file (in the My_Documents folder) . It always logs the lekseecon variables found in your config file.

    About your parking brake led: it looks like FSUIPC is not enabled. Please check your sioc.ini.

    Note also: I recently found a bug in lekseecon 7.0. It will not detect variable 508 (due to a bug in my configuration tables), however that will only have the effect that the leading mechanism is not working. If you have set your parking brake with your hardware switch, you can reset it with your mouse in the panel. I will correct that soon in version 7.1 However, that bug should have no effect on your problem. You should still get state information via the FSUIPC offset (if FSUIPC is enabled...?)

    Nico
    Last edited by kiek; 01-19-2011 at 09:40 AM.

Similar Threads

  1. Button functions
    By ANDYSMITH in forum FS2Phidget Users
    Replies: 1
    Last Post: 02-19-2010, 01:35 PM
  2. PM N1 Set and SPD Ref Functions.
    By Joe Lavery in forum Project Magenta User Group
    Replies: 2
    Last Post: 06-14-2009, 04:10 AM
  3. New fsuipc functions!
    By AndyT in forum Cockpit Software: Miscellaneous
    Replies: 0
    Last Post: 11-13-2008, 09:00 PM
  4. I need new hardware for various functions. Help
    By Simran737 in forum I/O Interfacing Hardware and Software
    Replies: 7
    Last Post: 09-23-2007, 10:41 AM